next up previous
Next: About this document ...

Studying the roles of different currents

Comp Neuroscience

Postscript Version of Notes

In this tutorial, we will explore the role of different currents on the firing properties of cortical neurons. It is based on a tutorial from the book of McCormick and Huguenard which is a DOS-based implementation of their model for thalamic and cortical neurons. The two papers that form the basis for this tutorial are in J. Neurophysiology 68:1373-1400 (1992). I have implemented their model in an xpp file which is given below and will also show you the equations. There are 11 conductances that are used. By changing them, you can look at different currents, turning them on and off as you'd like. The conductances are

gNa - sodium (microsiemens)
gNap - persistent sodium
gK - delayed rectifier
gK2 - slow potassium
pT - permeability for T-type calcium (10-6 cm3/sec)
pL - permeability for L-type calcium (10-6 cm3/sec)
gC - fast calcium/voltage depoendent potassium
gA - A-current
gH - Sag current
gM - slow muscarinic potassium current
gAHP - slow calcium-dependent potassium
gKleak - potassium leak
gNaleak - sodium leak


Here is the file

# the McCormick-Huguenard channel models -- Mix and match as you like
#
# UNITS: millivolts, milliseconds, nanofarads, nanoamps, microsiemens
# moles
# cell is 29000 micron^2 in area so capacitance is in nanofarads
# all conductances are in microsiemens and current is in nanofarads.
#
par I=0,c=.29
v'=(I -ina-ik-ileak-ik2-inap-it-iahp-im-ia-ic-il-ih+istep(t))/c
# the current is a step function with amplitude ip
istep(t)=ip*heav(t-t_on)*heav(t_off-t)
par ip=0.0,t_on=100,t_off=200
# passive leaks
par gkleak=.007,gnaleak=.00265
Ileak=gkleak*(v-ek)+gnaleak*(v-ena)
#
aux i_leak=ileak
#  INA
par gna=0,Ena=45
Ina=gna*(v-ena)*mna^3*hna
amna=.091*(v+38)/(1-exp(-(v+38)/5)) 
bmna=-.062*(v+38)/(1-exp((v+38)/5))
ahna=.016*exp((-55-v)/15)
bhna=2.07/(1+exp((17-v)/21))
mna'=amna*(1-mna)-bmna*mna
hna'=ahna*(1-hna)-bhna*hna
#
aux i_na=ina
# Delayed rectifier IK
par gk=0,Ek=-105
Ik=gk*(v-ek)*nk^4
ank=.01*(-45-v)/(exp((-45-v)/5)-1)
bnk=.17*exp((-50-v)/40)
nk'=ank*(1-nk)-bnk*nk
#
aux i_k=ik
# INap  same tau as Na but diff activation
par gnap=0
inap=gnap*map^3*(v-ena)
map'=(1/(1+exp((-49-v)/5))-map)/(amna+bmna)
#
aux i_nap=inap
# ia  A-type inactivating potassium current
#
ia=ga*(v-ek)*(.6*ha1*ma1^4+.4*ha2*ma2^4)
mainf1=1/(1+exp(-(v+60)/8.5))
mainf2=1/(1+exp(-(v+36)/20)) 
tma=(1/(exp((v+35.82)/19.69)+exp(-(v+79.69)/12.7))+.37)
ma1'=(mainf1-ma1)/tma
ma2'=(mainf2-ma2)/tma
hainf=1/(1+exp((v+78)/6))
tadef=1/(exp((v+46.05)/5)+exp(-(v+238.4)/37.45))
tah1=if(v<(-63))then(tadef)else(19)
tah2=if(v<(-73))then(tadef)else(60)
ha1'=(hainf-ha1)/tah1
ha2'=(hainf-ha2)/tah2
par ga=0
aux i_a=ia
#
# Ik2  slow potassium current
par gk2=0,fa=.4,fb=.6
Ik2=gk2*(v-ek)*mk2*(fa*hk2a+fb*hk2b)
minfk2=1/(1+exp(-(v+43)/17))^4
taumk2=1/(exp((v-80.98)/25.64)+exp(-(v+132)/17.953))+9.9
mk2'=(minfk2-mk2)/taumk2
hinfk2=1/(1+exp((v+58)/10.6))
tauhk2a=1/(exp((v-1329)/200)+exp(-(v+129.7)/7.143))+120
tauhk2b=if((v+70)<0)then(8930)else(tauhk2a)
hk2a'=(hinfk2-hk2a)/tauhk2a
hk2b'=(hinfk2-hk2b)/tauhk2b
aux i_k2=ik2
#
# IT and calcium dynamics -- transient low threshold
# permeabilites in 10-6 cm^3/sec
#
par Cao=2e-3,temp=23.5,pt=0,camin=50e-9 
number faraday=96485,rgas=8.3147,tabs0=273.15
# CFE stuff
xi=v*faraday*2/(rgas*(tabs0+temp)*1000)
# factor of 1000 for millivolts
cfestuff=2e-3*faraday*xi*(ca-cao*exp(-xi))/(1-exp(-xi))
IT=pt*ht*mt^2*cfestuff
mtinf=1/(1+exp(-(v+52)/7.4))
taumt=.44+.15/(exp((v+27)/10)+exp(-(v+102)/15))
htinf=1/(1+exp((v+80)/5))
tauht=22.7+.27/(exp((v+48)/4)+exp(-(v+407)/50))
mt'=(mtinf-mt)/taumt
ht'=(htinf-ht)/tauht
# il   L-type noninactivating calcium current -- high threshold
par pl=0
il=pl*ml^2*cfestuff
aml=1.6/(1+exp(-.072*(V+5)))
bml=.02*(v-1.31)/(exp((v-1.31)/5.36)-1)
ml'=aml*(1-ml)-bml*ml
aux i_l=il
# calcium concentration
par depth=.1,beta=1,area=29000
ca'=-.00518*(it+il)/(area*depth)-beta*(ca-camin)
ca(0)=50e-9
aux i_t=it
# ic  calcium and voltage dependent fast potassium current
ic=gc*(v-ek)*mc
ac=250000*ca*exp(v/24)
bc=.1*exp(-v/24)
mc'=ac*(1-mc)-bc*mc
par gc=0
aux i_c=ic
# ih  Sag current -- voltage inactivated inward current
ih=gh*(V-eh)*y
yinf=1/(1+exp((v+75)/5.5))
ty=3900/(exp(-7.68-.086*v)+exp(5.04+.0701*v))
y'=(yinf-y)/ty
par gh=0,eh=-43
# im   Muscarinic slow voltage gated potassium current
im=gm*(v-ek)*mm
mminf=1/(1+exp(-(v+35)/10))
taumm=taumm_max/(3.3*(exp((v+35)/20)+exp(-(v+35)/20)))
mm'=(mminf-mm)/taumm
par gm=0,taumm_max=1000
aux i_m=im
# Iahp  Calcium dependent potassium current 
Iahp=gahp*(v-ek)*mahp^2
par gahp=0,bet_ahp=.001,al_ahp=1.2e9
mahp'=al_ahp*ca*ca*(1-mahp)-bet_ahp*mahp
aux i_ahp=iahp
aux cfe=cfestuff
#  set up for 1/2 sec simulation in .5 msec increments
@ total=500,dt=.5,meth=qualrk,atoler=1e-4,toler=1e-5,bound=1000
@ xhi=500,ylo=-100,yhi=50
init v=-63,hna=.39,nk=.02,mna=.008
done

It is pretty big and this is only a single compartment model! To load this up click here now.

The initial file is set up for a passive membrane. Change ip to 0.25 nA. Run the simulation. You will see the potential rise. Calculate the equilibrium potential with this much current. Calculate the time-constant of the membrane using the values for the leak conductances and the capacitance.

Spikes!

Now set gNa=12 and gK=2. Rerun the simulation. How many spikes? What is the firing frequency of the cell? Block the potassium current by setting gK=0. What happens? The cell is ``bistable'' there are two stable states a high potential and a low potential. What accounts for the initial drop in the potential shortly after the stimulus is turned on?

A-Current
Set gK=1, gA=1, gNa=12. What does the A-current do? Compare the actual currents (called I_A, I_K in the program.

After-hyperpolarization
Set the total simulation time to 1000 msec. Set the stimulus, t_on=50, t_off=250, ip=1. Now turn on the L-type calcium current, pl=40 and set gk=1, gnaleak=.0024, gk=1. Run the simulation. Now add a small AHP current gAHP=.02. Compare the two. There is a large after-hyperpolarization that lasts for a second or so! Spike adaptation has also occurred. The first interspike interval is much smaller than the next several.

Rebound burst with T-current
Set ip=0, t_on=50, t_off=150, pT=40, pL=70, gK=1, gA=1, gNa=12 Integrate the equations and then reintegrate them using the Initial conds Last option to get rid of any transients. Now set ip=-.25 and thus hyperpolarize the membrane. You will get a rebound burst. Plot ht the inactivation of the T-current. Notice that hyperpolarization increases the value of this gate. Plot mt the activation gate on the same plot. Notice that the inactivation is slow so that when the hyperpolarization is removed, the channel is now open sufficiently to allow calcium to enter the cell and BAM! we get a burst. This is important for the workings of the thalamus which is surrounded by a thin layer of cells that are strictly inhibitory called the reticularis (RE). The thalamo-cortical (TC) units that project from the thalamus to the cortex have a large T-current. When they are inhibited by the RE cells, they produce a rebound burst. These bursts are believed to be responsible for sleep spindles.

Calcium oscillations
Thalamic relay cells can generate intrinsic oscillations via an interaction between the T-current and the sag current, I_h. Set all conductances to zero and then set ip=0 and the total integration time to 1500 msec. Set gnaleak=.00025,gkleak=.007, gK2=.2, pT=60, pL=80, gC=0.2, gA=1, gH=.01. Integrate the equations. Turn of the sag gH=0 and reintegrate them. What happens to the behavior? Turn the sag back on and add sodium spikes by setting gNa=14. Describe the behavior. Why is the period longer? (Hint - it has to do with the sag current.)


There are many other experiments you can do with this complicated model.

As a final exercise, I want you to look at a phase-plane analysis of a simplifed model for the T-current. In this model, there is only the T-current and a leak current. The activation of the calcium current is made instantaneous and thus the model is just a 2 dimensional system. I have also used the linear conductance model. Here are the equations:

#  T-current model
init v=-94,ht=.95
par I=0,c=.29
par ip=0,t_on=50,t_off=150
v'=(I -ileak-it+istep(t))/c
istep(t)=ip*heav(t-t_on)*heav(t_off-t)
# the current is a step function with amplitude ip
# passive leaks
par ena=45,ek=-105,eca=145
par gkleak=.007,gnaleak=.0005
Ileak=gkleak*(v-ek)+gnaleak*(v-ena)
#
aux i_leak=ileak
#
# IT and calcium dynamics -- transient low threshold
# permeabilites in 10-6 cm^3/sec
#
par gt=2
IT=gt*ht*mt^2*(v-eca)
mt=1/(1+exp(-(v+52)/7.4))
htinf=1/(1+exp((v+80)/5))
tauht=22.7+.27/(exp((v+48)/4)+exp(-(v+407)/50))
ht'=(htinf-ht)/tauht
@ dt=.25,total=500,xp=v,yp=ht,xlo=-100,xhi=40,ylo=-.1,yhi=1
@ nmesh=100,bounds=1000
done
If you fire this up, you will be in the (V,ht) phase-plane. Answer the following questions
1.
How many fixed points are there? Which are stable?
2.
Starting at rest, would a depolarizing or hyperpolarizing stimulus elicit a spike? Try using ip small positive and negative to verify your answer.
3.
Change gnaleak = .001 and redraw the nullclines. How many fixed points are there and what is their stability?
4.
Integrate the equations. What behavior do you find? (Don't forget to set ip=0.
5.
Increase the sodium leak to 0.003. Draw the nullclines. It might help to change the y-axis to -.05 to .1. How could one elicit a spike in this case? (Hint, what does changing the current, I do to the nullclines. Try I=-.25, .25 to see what happens to the fixed point.
6.
Set I=0 and try different values for the current pulse, ip say -.25 and .25. You should be able see a rebound calcium spike.


 
next up previous
Next: About this document ...
G. Bard Ermentrout
1/26/1998